Arduino:Примеры/KeyboardReprogram

Содержание

Знакомство с Arduino

Продукты

Основы

Справочник языка Arduino

Примеры

Библиотеки

Хакинг

Изменения

Сравнение языков Arduino и Processing

Перевод: Максим Кузьмин

Проверка/Оформление/Редактирование: Мякишев Е.А.

Перепрограммирование Arduino при помощи клавиатурных команд

В этом примере библиотека Keyboard используется для того, чтобы открыть новое окно для скетча Arduino, затем напечатать в нем программу, аналогичную примеру «Моргание», и тем самым перепрограммировать плату. Таким образом, после запуска этого скетча и подключения 2-ого цифрового контакта к контакту с «землей» на Arduino будет стоять новая программа.

Внимание! При использовании команды Keyboard.print() Arduino перехватит роль клавиатуры на себя. Поэтому, перед тем как вызывать эту команду, убедитесь, что вы все настроили правильно, чтобы внезапно не потерять контроль над компьютером при использовании этого скетча. Его задача заключается лишь в том, чтобы отправить на компьютер клавиатурную команду после того, как 2-ой цифровой контакт будет подключен к «земле».

Необходимое оборудование

• Плата Arduino Leonardo, Arduino Micro или Arduino Due;
• Провод-перемычка;

Необходимое ПО

• Среда разработки Arduino;

Цепь

Подключите Arduino к компьютеру при помощи microUSB-кабеля. Чтобы запустить скетч, при помощи провода-перемычки заземлите 2-ой цифровой контакт. Чтобы все прошло как надо, программа Arduino должна запуститься в качестве главного приложения.

Код

/*
  Перепрограммирование Arduino в пример «Моргание»
 
  Этот скетч демонстрирует использование библиотеки Keyboard.
 
  Когда 2-ой цифровой контакт подключается к «земле»,
 Arduino создает новое окно при помощи комбинации клавиш Ctrl+N,
 затем впечатывает туда скетч из примера «Моргание»,
 делает автоформатирование текста с помощью комбинации Ctrl+T,
 а после загружает новый скетч в текущую Arduino 
 при помощи комбинации Ctrl+U.
 
 Цепь:
 * Плата Arduino Leonardo или Arduino Micro
 * Провод-перемычка, соединяющий 2-ой цифровой контакт с «землей».
 
 Создан 5 марта 2012,
 модифицирован 29 марта 2012 Томом Иго (Tom Igoe).
 
 Этот код не защищен авторским правом.
 
 http://www.arduino.cc/en/Tutorial/KeyboardReprogram
 */

// Используйте эту строку кода для OSX. 
// Если используете Windows или Linux, прикройте ее комментированием.
char ctrlKey = KEY_LEFT_GUI;
// Используйте эту строку для Windows и Linux.
// Оставьте закомментированной, если используете OSX:
//  char ctrlKey = KEY_LEFT_CTRL;


void setup() {
  // Делаем 2-ой цифровой контакт входным контактом
  // и активируем подтягивающий резистор, 
  // чтобы на контакте всегда было HIGH,
  // пока он не будет соединен с «землей»:
  pinMode(2, INPUT_PULLUP);
  // Перехватываем управление клавиатурой:
  Keyboard.begin();
}

void loop() {
  while (digitalRead(2) == HIGH) {
    // Ничего не делаем, пока на 2-ом контакте не будет значение LOW:
    delay(500);
  }
  delay(1000);
  // Создаем новый документ:
  Keyboard.press(ctrlKey);
  Keyboard.press('n');
  delay(100);
  Keyboard.releaseAll();
  // Ждем, пока новое окно откроется:
  delay(1000);

  // Впечатываем в это окно пример «Моргание»:
  Keyboard.println("void setup() {");
  Keyboard.println("pinMode(13, OUTPUT);");
  Keyboard.println("}");
  Keyboard.println();
  Keyboard.println("void loop() {");
  Keyboard.println("digitalWrite(13, HIGH);");
  Keyboard.print("delay(3000);");
  // 3000 миллисекунд – это много. Удаляем последние 6 символов:
  for (int keystrokes=0; keystrokes < 6; keystrokes++) {
    delay(500);
    Keyboard.write(KEY_BACKSPACE); 
  }
// Вписываем 1000 миллисекунд:
  Keyboard.println("1000);");
  Keyboard.println("digitalWrite(13, LOW);");
  Keyboard.println("delay(1000);");
  Keyboard.println("}");
  // Делаем автоформатирование:
  Keyboard.press(ctrlKey);
  Keyboard.press('t');
  delay(100);
  Keyboard.releaseAll();
  delay(3000);
  // Загружаем код:
  Keyboard.press(ctrlKey);
  Keyboard.press('u');
  delay(100);
  Keyboard.releaseAll();

  // Ждем, пока Arduino забудет свою предыдущую программу и перепрограммируется:
  while(true);
}

См.также

1. Keyboard.write()
2. Keyboard.print()
3. Keyboard.println()