Arduino:Примеры/LiquidCrystalScroll

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Перевод: Максим Кузьмин (Cubewriter) Контакты:</br>* Skype: cubewriter</br>* E-mail: cubewriter@gmail.com</br>* Максим Кузьмин на freelance.ru
Проверка/Оформление/Редактирование: Мякишев Е.А.


ЖК-экран – движение текста [1]

Библиотека LiquidCrystal позволяет вам управлять ЖК-экранами, которые совместимы с драйвером Hitachi HD44780. Моделей этих экранов встречается довольно много, а их управление осуществляется, как правило, через 16-контактный интерфейс.

Этот пример показывает, как использовать функции scrollDisplayLeft() и scrollDisplayRight() для того, чтобы менять направление двигающегося текста. Если точнее, этот скетч сначала выводит на дисплей надпись «Hello, World!», затем уводит текст за левый край экрана, потом за правый край и в конце концов возвращает его «домой».

Необходимое оборудование:

  • Плата Arduino;
  • ЖК-экран (совместимый с драйвером Hitachi HD44780);
  • Штырьковые соединители, припаянные к контактам ЖК-экрана;
  • Потенциометр на 10 кОм;
  • Макетная плата Breadboard;
  • Провода-перемычки;

Цепь

Перед тем, как подключать ЖК-экран к Arduino, нам надо припаять линейку штырьковых соединителей к коннектору с 14 (или 16) контактами. Затем, при подключении ЖК-экрана к Arduino, нужно соединить следующие контакты:

  • RS – с 12-ым цифровым контактом
  • Enable – с 11-ым цифровым контактом
  • D4 – с 5-ым цифровым контактом
  • D5 – с 4-ым цифровым контактом
  • D6 – с 3-им цифровым контактом
  • D7 – со 2-ым цифровым контактом

Также подсоединяем 10 кОмовый потенциометр: концы – к +5V и Gnd, а движок – к контакту Vo ЖК-экрана.

LCD bb LiquidCrystalScroll.png

Схема

LCD schem LiquidCrystalScroll.png

Код

/*
Библиотека LiquidCrystal – движение текста
 
Демонстрирует использование ЖК-дисплея 16х2. Библиотека LiquidCrystal
работает со всеми ЖК-дисплеями, которые совместимы с драйвером Hitachi HD44780. Моделей, отвечающих этим критериям, довольно много,
а управлять ими можно, как правило, при помощи 16-контактного интерфейса.

Этот скетч выводит на дисплей надпись «Hello, World!»,
а затем при помощи функций scrollDisplayLeft() и scrollDisplayRight()
двигает текст то влево, то вправо.

Цепь (ЖК-экран):
* Контакт RS подключаем к 12-ому цифровому контакту
* Контакт Enable – к 11-ому цифровому контакту 
* Контакт D4 – к 5-ому цифровому контакту
* D5 – к 4-ому цифровому контакту
* D6 – к 3-ему цифровому контакту
* D7 – ко 2-ому цифровому контакту
* Контакт R/W – к «земле»

Цепь (10000-омовый потенциометр):
* концы – к +5V и «земле»
* движок – к Vo (т.е. к 3-ему контакту)

Первоначально библиотека добавлена 18 апреля 2008 Дэвидом А. Меллисом (David A. Mellis),
а модифицирована 5 июля 2009 Лимор Фрид (Limor Fried, http://www.ladyada.net).

Пример добавлен 9 июля 2009 Томом Иго (Tom Igoe),
модифицирован 22 ноября 2010 им же.
 
Этот код не защищен авторским правом.

http://arduino.cc/en/Tutorial/LiquidCrystalScroll
*/

// Подключаем код библиотеки:
#include <LiquidCrystal.h>

// Инициализируем библиотеку, указывая номера используемых контактов Arduino:
LiquidCrystal lcd(12, 11, 5, 4, 3, 2);

void setup() {
  // Задаем количество столбцов и рядов ЖК-экрана: 
  lcd.begin(16, 2);
  // Показываем на дисплее сообщение:
  lcd.print("hello, world!");  //  "Привет, мир!"
  delay(1000);
}

void loop() {
  // Двигаем текст на 13 позиций (это длина строки) влево, 
  // тем самым полностью пряча его за левый край экрана:
  for (int positionCounter = 0; positionCounter < 13; positionCounter++) {
    // Начинаем движение:
    lcd.scrollDisplayLeft(); 
    // Немножко ждем:
    delay(150);
  }

  // Двигаем текст на 29 позиций вправо 
  // (это длина строки плюс длина дисплея),
  // тем самым полностью пряча его за правый край экрана:  
  for (int positionCounter = 0; positionCounter < 29; positionCounter++) {
    // Начинаем движение:
    lcd.scrollDisplayRight(); 
    // Немножко ждем:
    delay(150);
  }
  
  // Двигаем текст на 16 позиций влево 
  // (это длина дисплея плюс длина строки),
  // тем самым возвращая его в центр:    
  for (int positionCounter = 0; positionCounter < 16; positionCounter++) {
    // Начинаем движение:
    lcd.scrollDisplayLeft(); 
    // Немножко ждем:
    delay(150);
  }
  
  // В конце главного цикла делаем секундную задержку:
  delay(1000);

}

См.также

  1. lcd.begin()
  2. lcd.print()
  3. lcd.scrollDisplayLeft()
  4. lcd.scrollDisplayRight()
  5. Liquid Crystal Library
  6. Blink: control of the block-style cursor.
  7. Cursor: control of the underscore-style cursor.
  8. Display: quickly blank the display without losing what's on it.
  9. TextDirection: control which way text flows from the cursor.
  10. Serial input: accepts serial input, displays it.
  11. SetCursor: set the cursor position.
  12. Autoscroll: shift text right and left.

Внешние ссылки