Arduino:Примеры/Series1 IoSamples

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Перевод: Максим Кузьмин (Cubewriter) Контакты:</br>* Skype: cubewriter</br>* E-mail: cubewriter@gmail.com</br>* Максим Кузьмин на freelance.ru
Проверка/Оформление/Редактирование: Мякишев Е.А.


Получение данных от удаленного XBee-модуля[1]

Этот пример показывает, как при помощи библиотеки XBee настроить XBee-модуль на получение данных от удаленного XBee-модуля.

Код

/**
 * Автор – Эндрю Рэпп (Andrew Rapp). 2009 год, все права защищены.
 *
 * Этот файл – часть библиотеки XBee-Arduino.
 *
 * Библиотека XBee для Arduino – это бесплатное ПО: его можно 
 * распространять и/или модифицировать согласно условиям Универсальной 
 * общественной лицензии GNU, изданной Фондом свободного ПО – будь то 
 * 3-тья или более поздняя версия этой лицензии (на ваш выбор).
 *
 * Библиотека XBee-Arduino распространяется бесплатно в надежде на то, 
 * что окажется полезной, но БЕЗО ВСЯКОЙ ГАРАНТИИ; включая даже 
 * обязательную гарантию на КОММЕРЧЕСКОЕ КАЧЕСТВО и ПРИГОДНОСТЬ 
 * КОНКРЕТНОЙ ЦЕЛИ. Более подробно читайте в Универсальной 
 * общественной лицензии GNU.
 *
 * Вы должны получить копию Универсальной общественной лицензии GNU 
 * вместе с библиотекой XBee-Arduino. Если не получили, ее можно найти 
 * на http://www.gnu.org/licenses/.
*/

#include <XBee.h>
#include <SoftwareSerial.h>

/*
Этот пример – только для XBee-модулей типа Series 1. Он принимает 
данные от удаленного XBee-модуля с 16-битным адресом. У удаленного 
XBee-модуля IR должно быть больше «0», должен быть активирован как 
минимум один цифровой или аналоговый входной контакт, а также DL 
должен быть выставлен на 16-битный адрес принимающего XBee-модуля 
(того, что подключен к Arduino).

Чтобы видеть информацию об XBee-коммуникации, этот пример использует 
библиотеку SoftSerial. Я использую плату Modern Device USB BUB
(http://moderndevice.com/connect) и просматриваю выдачу при помощи 
монитора порта в IDE Arduino.
*/

// Задаем TX и RX контакты для NewSoftSerial.
// Подключаем 8-ой контакт Arduino к TX-контакту конвертера USB-Serial:
uint8_t ssRX = 8; 
// Подключаем 9-ый контакт Arduino к RX-контакту конвертера USB-Serial:
uint8_t ssTX = 9;
// Не забудьте подключить все устройства к общей «земле»: XBee, 
// Arduino и конвертер USB-Serial
SoftwareSerial nss(ssRX, ssTX);

XBee xbee = XBee();

Rx16IoSampleResponse ioSample = Rx16IoSampleResponse();
// 64-битный ответ – тот же, за исключением того, что API ID 
// эквивалентен RX_64_IO_RESPONSE и возвращает 64-битный адрес:
//Rx64IoSampleResponse ioSample = Rx64IoSampleResponse();

void setup() { 
  Serial.begin(9600);
  xbee.setSerial(Serial);
  // Запускаем коммуникацию SoftSerial:
  nss.begin(9600);
}

void loop() {
  // Пытаемся прочесть пакет: 
  xbee.readPacket();

  if (xbee.getResponse().isAvailable()) {
    // Что-то получили

    if (xbee.getResponse().getApiId() == RX_16_IO_RESPONSE) {
      xbee.getResponse().getRx16IoSampleResponse(ioSample);

      nss.print("Received I/O Sample from: ");  //  "Получили I/O порцию от: "
      nss.println(ioSample.getRemoteAddress16(), HEX);  

      nss.print("Sample size is ");  //  "Размер порции "
      nss.println(ioSample.getSampleSize(), DEC);

      if (ioSample.containsAnalog()) {
        nss.println("Sample contains analog data");    //  "Порция содержит аналоговые данные "
      }

      if (ioSample.containsDigital()) {
        nss.println("Sample contains digital data");  //  "Порция содержит цифровые данные"
      }
      
      for (int k = 0; k < ioSample.getSampleSize(); k++) {
        nss.print("Sample ");  //  "Порция "
        nss.print(k + 1, DEC);   
        nss.println(":");    
        
        for (int i = 0; i <= 5; i++) {
          if (ioSample.isAnalogEnabled(i)) {
            nss.print("Analog (AI");  //  "Аналоговый (АI"
            nss.print(i, DEC);
            nss.print(") is ");
            nss.println(ioSample.getAnalog(i, k));  
          }
        }
        
        for (int i = 0; i <= 8; i++) {
           if (ioSample.isDigitalEnabled(i)) {
            nss.print("Digtal (DI");   //  "Цифровой (АI"
            nss.print(i, DEC);
            nss.print(") is ");
            nss.println(ioSample.isDigitalOn(i, k));
          }
        }
      }
    } 
    else {
      nss.print("Expected I/O Sample, but got ");  //  "Ожидалась I/O порция, но получили "
      nss.print(xbee.getResponse().getApiId(), HEX);
    } 
  } 
  else if (xbee.getResponse().isError()) {
    nss.print("Error reading packet.  Error code: ");  //  "Ошибка при чтении пакета. Код ошибки: "
    nss.println(xbee.getResponse().getErrorCode());
  }
}

См.также

Внешние ссылки