Arduino:Примеры/fft adc serial

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Перевод: Максим Кузьмин (Cubewriter) Контакты:</br>* Skype: cubewriter</br>* E-mail: cubewriter@gmail.com</br>* Максим Кузьмин на freelance.ru
Проверка/Оформление/Редактирование: Мякишев Е.А.


Применение БПФ на данных от АЦП и отправка результата посредством println()[1]

Это скетч для библиотеки FFT, который при помощи платы Arduino считывает данные с АЦП (аналогово-цифрового преобразователя), а затем обрабатывает их при помощи алгоритма БПФ (быстрое преобразование Фурье).

Для передачи данных по последовательному порту используется цикл for() и функция println().

Код

 
/*
Применение БПФ на данных от АЦП и отправка результата через printIn()

Создан пользователем guest на openmusiclabs.com
Дата создания – 7 июля 2014 года.
Скетч предназначен для тестирования библиотеки FFT.

Он берет данные у adc0 (0—ой аналоговый контакт), а затем 
обрабатывает их при помощи БПФ. Данные отправляются 
по последовательному порту на скорости 115,2 килобит.
*/

#define LOG_OUT 1 // включаем функцию для логарифмического формата
#define FFT_N 256 // задаем количество выходных отсчетов на 256

#include <FFT.h> // подключаем библиотеку

void setup() {
  Serial.begin(115200); // запускаем последовательный порт
  TIMSK0 = 0; // выключаем timer0, чтобы уменьшить джиттер
  ADCSRA = 0xe5; // задаем для АЦП автономный режим работы
  ADMUX = 0x40; // используем adc0
  DIDR0 = 0x01; // выключаем цифровой вход для adc0
}

void loop() {
  while(1) { // уменьшаем джиттер
    cli();  // на Arduino 1.0 со снижением хорошо справляются прерывания UDRE 
    for (int i = 0 ; i < 512 ; i += 2) { // сохраняем 256 отчетов
      while(!(ADCSRA & 0x10)); // ждем, когда АЦП будет готов
      ADCSRA = 0xf5; // перезапускаем АЦП
      byte m = ADCL; // считываем данные АЦП
      byte j = ADCH;
      int k = (j << 8) | m; // конвертируем в данные типа int
      k -= 0x0200; // конвертируем в данные типа int со знаком
      k <<= 6; // конвертируем в 16-битные данные типа int со знаком
      fft_input[i] = k; // сохраняем действительные значения в четные отсчеты
      fft_input[i+1] = 0; // задаем нечетным отсчетам значение «0»
    }
    fft_window(); // функция-окно, повышающая частотное разрешение
    fft_reorder(); // реорганизовываем данные перед запуском БПФ
    fft_run(); // обрабатываем данные в БПФ
    fft_mag_log(); // извлекаем данные, обработанные БПФ
    sei();
    Serial.println("start");  //  "Старт"
    for (byte i = 0 ; i < FFT_N/2 ; i++) { 
      Serial.println(fft_log_out[i]); // отсылаем данные
    }
  }
}

См.также

Внешние ссылки