Arduino:Примеры/ArduinoController

Содержание

Знакомство с Arduino

Продукты

Основы

Справочник языка Arduino

Примеры

Библиотеки

Хакинг

Изменения

Сравнение языков Arduino и Processing

Перевод: Максим Кузьмин

Проверка/Оформление/Редактирование: Мякишев Е.А.

Контроллер Arduino

Этот пример является расширенной версией примера «Получение команд», то есть демонстрирует, как сделать на PC переключатель светодиода, встроенного в Arduino, но вдобавок к этому – то, как задать частоту мигания светодиода.

Код

// *** ArduinoController ***

// Это расширенная версия примера «Получение команд». В него
// добавлено то, что пользователь может задать частоту мигания 
// светодиода.
// 
// Этот скетч демонстрирует, как:
// - обрабатывать входящие команды, к которым не привязаны функции 
// - отправлять на PC команду с аргументом
// - инициировать основной поток 

#include <CmdMessenger.h>  // CmdMessenger

// переменные для мигающего светодиода: 
const int kBlinkLed            = 13;  // контакт для встроенного светодиода
bool ledState                  = 1;   // текущее состояние светодиода
float ledFrequency             = 1.0; // текущая частота мигания светодиода

unsigned long intervalOn;
unsigned long intervalOff;
unsigned long prevBlinkTime = 0;

// привязываем экземпляр класса CmdMessenger к последовательному порту:
CmdMessenger cmdMessenger = CmdMessenger(Serial);

// Это список распознаваемых команд, и эти команды могут быть 
// либо получены, либо отправлены. Чтобы получить команду, к этому 
// событию нужно привязать функцию внешнего вызова.
enum
{
  kAcknowledge,
  kError,
  kSetLed, // команда, запрашивающая, чтобы светодиод был переключен в определенное состояние
  kSetLedFrequency,
};

// функции внешнего вызова, определяющие, при получении каких команд нам нужно начинать действовать:
void attachCommandCallbacks()
{
  // подключаем функции внешнего вызова:
  cmdMessenger.attach(OnUnknownCommand);
  cmdMessenger.attach(kSetLed, OnSetLed);
  cmdMessenger.attach(kSetLedFrequency, OnSetLedFrequency);
}

// эта функция вызывается, когда к присланной команде не привязано никакой функции:
void OnUnknownCommand()
{
  cmdMessenger.sendCmd(kError,"Command without attached callback");  //  "Команда без функции внешнего вызова"
} 

// функция внешнего вызова, включающая/выключающая светодиод:
void OnSetLed()
{
  // считываем присланный аргумент, интерпретируем строку как boolean:
  ledState = cmdMessenger.readBoolArg();
  cmdMessenger.sendCmd(kAcknowledge,ledState);
}

// функция внешнего вызова, задающая частоту мигания светодиода:
void OnSetLedFrequency()
{
  // считываем присланный аргумент, интерпретируем строку как boolean:
  ledFrequency = cmdMessenger.readFloatArg();
  // проверяем, что частота не равна нулю (чтобы предотвратить деление на ноль)
  if (ledFrequency < 0.001) { ledFrequency = 0.001; }
  // конвертируем частоту в интервалы включения/выключения (в миллисекундах):
  intervalOn  = (500.0/ledFrequency);
  intervalOff = (1000.0/ledFrequency);
  cmdMessenger.sendCmd(kAcknowledge,ledFrequency);
}

// блок исходных операций:
void setup() 
{
  // прослушиваем последовательное соединение на предмет сообщений от PC:
  Serial.begin(115200);

  // добавляем к каждой команде символ новой строки:
  //cmdMessenger.printLfCr();   

  // подключаем функции внешнего вызова, заданные пользователем:
  attachCommandCallbacks();

  // отсылаем на PC сообщение о загрузке Arduino; также обратите 
  // внимание, что это хороший способ отладки – эта функция даст 
  // знать, если в скетче есть баг и Arduino была перезапущена:
  cmdMessenger.sendCmd(kAcknowledge,"Arduino has started!");  //  "Arduino запущена!"

  // режим работы светодиода выставляем на OUTPUT:
  pinMode(kBlinkLed, OUTPUT);
}

// блок повторяющихся операций:
void loop() 
{
  // обрабатываем данные, пришедшие по последовательному соединению,
  // и выполняем функции внешнего вызова:
  cmdMessenger.feedinSerialData();
  delay(10);
  blinkLed();
}

// возвращаем «true», если время превысило заданный интервал 
// (в миллисекундах); используется для периодических действий:
void blinkLed() {
  if (  millis() - prevBlinkTime > intervalOff ) {
    // выключаем светодиод в середине заданного интервала:
    prevBlinkTime = millis();
    digitalWrite(kBlinkLed, LOW);
  } else if (  millis() - prevBlinkTime > intervalOn ) {
    // включаем светодиод в конце заданного интервала (если состояние светодиода – это «вкл»):
    digitalWrite(kBlinkLed, ledState?HIGH:LOW);
  } 
}