Cat hungry.png
Здравствуйте! Собираем деньги на перевод материалов по электронике(https://www.allaboutcircuits.com/education/). Реквизиты указаны здесь.

Arduino:Примеры/RobotDiscoBot

Материал из Онлайн справочника
Перейти к: навигация, поиск

Перевод: Максим Кузьмин (Cubewriter)
Перевел 2686 статей для сайта.

Контакты:

Проверка/Оформление/Редактирование: Мякишев Е.А.


Диско-бот[1]

Этот скетч демонстрирует, как при помощи робота проигрывать мелодии, основанные на звуковых файлах.

При помощи кнопок, находящихся на верхней (контрольной) плате, вы сможете выбирать между тремя мелодиями, созданными специально для Arduino Robot. Выбрав понравившуюся мелодию, поставьте робота на пол, после чего он с удовольствием вам станцует.

Необходимое оборудование

  • Arduino Robot;
  • Ваш лучший танцевальный костюм;

Инструкция

  1. Загрузите скетч, отключите USB и включите питание
  2. Поставьте робота на пол
  3. Показав экран загрузки, робот начнет танцевать под музыку и мигать на дисплее разными цветами
  4. Переключать музыку можно при помощи кнопок «Влево» и «Вправо»
  5. Если танцевальные движения робота вас не устраивают, найдите в скетче строчку
    1. char danceScript[]="S4L1R1S2F1B1S1\0"
    и измените ее. Вся эта абракадабра расшифровывается следующим образом:
  • «S» – стоп,
  • «L» – поворот влево,
  • «R» – поворот вправо,
  • «F» – движение вперед,
  • «B» – движение назад.

Номер возле каждой команды означает то, сколько она будет длиться. То есть

  • «1» – это 500 миллисекунд,
  • «2» – 1000 миллисекунд,
  • «3» – 1500 миллисекунд и т.д.

Пробуем

LottieLemon illustration Disco 780.png

Выбираем мелодию

Код

  1. /* Диско-бот
  2.  
  3. Этот скетч демонстрирует, как у Arduino Robot работает функция
  4. проигрывания мелодий – у робота припасены для вас пара треков
  5. зажигательной 8-битной музыки. Музыка будет проигрываться, когда
  6. робот будет во включенном состоянии. Кроме того, он покажет вам пару
  7. интересных танцевальных движений.
  8.  
  9. Цепь:
  10. * Arduino Robot
  11.  
  12. Создан 1 мая 2013 Х. Янгом (X. Yang),
  13. модифицирован 12 мая 2013 Д. Куартиллье (D. Cuartielles).
  14.  
  15. Этот код не защищен авторским правом.
  16.  */
  17.  
  18. #include <ArduinoRobot.h> // подключаем библиотеку робота
  19. #include <Wire.h>
  20. #include <SPI.h>
  21.  
  22. /*
  23. Танцевальные «движения»:
  24. S: стоп
  25. L: поворот влево
  26. R: поворот вправо
  27. F: движение вперед
  28. B: движение назад
  29.  
  30. Цифра после каждой команды означает то, как долго будет длиться то или иное «движение». «1» – это полсекунды, «2» – секунда и т.д.
  31.  
  32. «\0» означает конец строки.
  33. */
  34.  
  35. char danceScript[] = "S4L1R1S2F1B1S1\0";
  36.  
  37. int currentScript = 0; // то, на каком шаге мы находимся
  38.  
  39. int currentSong = 0; // отслеживаем текущую песню
  40. static const int SONGS_COUNT = 3; // количество песен
  41.  
  42. // массив, в котором будут храниться песни:
  43. char musics[][11] = {
  44.   "melody.sqm",
  45.   "menu.sqm",
  46.   "chase.sqm",
  47. };
  48.  
  49. // Переменные для неблокирующей задержки:
  50. long waitFrom;
  51. long waitTime = 0;
  52.  
  53. void setup() {
  54.   // Инициализируем робота, SD-карту, дисплей и динамик:
  55.   Robot.begin();
  56.   Robot.beginSpeaker();
  57.   Robot.beginSD();
  58.   Robot.beginTFT();
  59.  
  60.   // Рисуем на экране картинки «lg0.bmp» и «lg1.bmp»:
  61.   Robot.displayLogos();
  62.  
  63.   // Печатаем на экране инструкции:
  64.   Robot.text("1. Use left and\n right key to switch\n song", 5, 5);  //  "Для переключения\n песни используем\n кнопки «Влево» \n и «Вправо»"
  65.   Robot.text("2. Put robot on the\n ground to dance", 5, 33);  //  "Чтобы робот начал\n танцевать, поставьте\n его на землю"
  66.  
  67.   // Ждем несколько секунд:
  68.   delay(3000);
  69.  
  70.   setInterface(); // показываем текущую песню
  71.   play(0);  // проигрываем первую песню в массиве
  72.  
  73.   resetWait();  // инициализируем неблокирующую задержку
  74. }
  75.  
  76. void loop() {
  77.   // Считываем состояния кнопок робота:
  78.   int key = Robot.keyboardRead();
  79.  
  80.   // Кнопки «Вправо» и «Влево» переключают на следующую песню:
  81.   switch (key) {
  82.     case BUTTON_UP:
  83.     case BUTTON_LEFT:
  84.       play(-1);  // проигрываем предыдущую песню
  85.       break;
  86.     case BUTTON_DOWN:
  87.     case BUTTON_RIGHT:
  88.       play(1);  // проигрываем следующую песню
  89.       break;
  90.   }
  91.  
  92.   // Танцуем!
  93.   runScript();
  94. }
  95.  
  96. // «Танцевальная» функция:
  97. void runScript() {
  98.   if (!waiting()) { // если робот выполнил предыдущую последовательность действий
  99.     // Берем следующие две команды:
  100.     parseCommand(danceScript[currentScript], danceScript[currentScript + 1]);
  101.     currentScript += 2;
  102.     if (danceScript[currentScript] == '\0') { // если добрались до конца массива
  103.       currentScript = 0;  // начинаем еще раз с самого начала
  104.     }
  105.   }
  106. }
  107.  
  108. // Используем этот таймер вместо стандартной задержки:
  109. boolean waiting() {
  110.   if (millis() - waitFrom >= waitTime) {
  111.     return false;
  112.   } else {
  113.     return true;
  114.   }
  115. }
  116.  
  117. // Как долго будем ждать:
  118. void wait(long t) {
  119.   resetWait();
  120.   waitTime = t;
  121. }
  122.  
  123. // Сбрасываем таймер:
  124. void resetWait() {
  125.   waitFrom = millis();
  126. }
  127.  
  128. // Считываем информацию о направлении и продолжительности «движений»:
  129. void parseCommand(char dir, char duration) {
  130.   // Трансформируем скрипт в действие:
  131.   switch (dir) {
  132.     case 'L':
  133.       Robot.motorsWrite(-255, 255);
  134.       break;
  135.     case 'R':
  136.       Robot.motorsWrite(255, -255);
  137.       break;
  138.     case 'F':
  139.       Robot.motorsWrite(255, 255);
  140.       break;
  141.     case 'B':
  142.       Robot.motorsWrite(-255, -255);
  143.       break;
  144.     case 'S':
  145.       Robot.motorsStop();
  146.       break;
  147.   }
  148.   // Если хотите поменять ритм танца, поменяйте цифру «500» на какую-нибудь еще:
  149.   wait(500 * (duration - '0'));
  150. }
  151.  
  152. // Отображаем на дисплее название песни:
  153. void setInterface() {
  154.   Robot.clearScreen();
  155.   Robot.stroke(0, 0, 0);
  156.   Robot.text(musics[0], 0, 0);
  157. }
  158.  
  159. // Отображаем следующую песню:
  160. void select(int seq, boolean onOff) {
  161.   if (onOff) { // выбираем
  162.     Robot.stroke(0, 0, 0);
  163.     Robot.text(musics[seq], 0, 0);
  164.   } else { // отменяем выбор
  165.     Robot.stroke(255, 255, 255);
  166.     Robot.text(musics[seq], 0, 0);
  167.   }
  168. }
  169.  
  170. // Проигрываем выбранную песню:
  171. void play(int seq) {
  172.   select(currentSong, false);
  173.   if (currentSong <= 0 && seq == -1) {
  174.     currentSong = SONGS_COUNT - 1; // переходим к последней песне
  175.   } else if (currentSong >= SONGS_COUNT - 1 && seq == 1) {
  176.     currentSong = 0;  // переходим к первой песне
  177.   } else {
  178.     currentSong += seq;  // следующая песня
  179.   }
  180.   Robot.stopPlayFile();
  181.   Robot.playFile(musics[currentSong]);
  182.   select(currentSong, true);  // отображаем на экране название текущей песни
  183. }

Изучаем дальше

Мелодии создаются при помощи трекера и хранятся на SD-карте. О том, как написать свой собственный трек, можно прочесть тут.

См.также

  1. begin()
  2. beginTFT()
  3. beginSD()
  4. beginSpeaker()
  5. playFile()
  6. motorsWrite()
  7. turn()

Внешние ссылки

  1. Arduino - Disco bot