Arduino:Примеры/Гайд по использованию RTC-модуля DS1307 или DS3231 с Arduino

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Перевод: Максим Кузьмин
Проверка/Оформление/Редактирование: Мякишев Е.А.



Гайд по использованию RTC-модуля DS1307 или DS3231 с Arduino[1]

Эта статья объясняет, как использовать RTC-модуль (от «real time clock», что значит «часы реального времени») DS1307 вместе с платой Arduino. Впрочем, данное руководство подойдет и для других RTC-модулей вроде DS3231. RTC-модуль можно использовать как часы, таймер и т.д.

Описание

На то, как выглядит RTC-модуль, можно посмотреть на картинке ниже (вид спереди и сзади).

Перед тем, как использовать RTC-модуль, вам нужно припаять к нему гребешок контактов.

Как видно на картинке выше, модуль оснащен запасной батарейкой. Благодаря этому модуль может по-прежнему считать время, даже не будучи подключенным к питанию от Arduino.

Другими словами, при каждом включении/выключении модуля время не сбрасывается.

Этот модуль использует коммуникацию типа I2C. Это значит, что он коммуницирует с Arduino при помощи всего 2 контактов.

Где купить?

RTC-модули стоят недорого и очень распространены. На eBay такой модуль можно купить примерно за 2 доллара.

Подключение контактов

В подключении RTC-модуля нет ничего сложного:

  • Контакт SCL на RTC-модуле – к контакту A5 на Arduino
  • Контакт SDA – к контакту A4
  • Контакт VCC – к контакту 5V
  • Контакт GND – к контакту GND

Если вы используете не Uno, а другую плату Arduino, то у нее контакты SCL и SDA могут находиться в других местах:

  • Arduino Nano: контакт SDA – это контакт A4, а SCL – это A5
  • Arduino MEGA и Arduino Leonardo: контакт SDA – это контакт 20, а SCL – это контакт 21

Скетч: Показ времени и даты на мониторе порта IDE Arduino

Схема

Подключите друг к другу RTC-модуль и плату Arduino в соответствии со схемой ниже:

Код

Для работы с RTC-модулем нужно сделать две важные вещи:

  • Настроить в скетче текущее время, чтобы RTC-модуль знал, сколько время.
  • Сделать так, чтобы текущее время не сбрасывалось, чтобы RTC-модуль всегда сообщал правильное время, даже будучи выключенным.

Настраиваем текущее время

Чтобы настроить текущее время, вам нужно поменять значения в функции setDS3231time().

Параметры этой функции выделены красным и расположены в следующем порядке: секунды, минуты, часы, дни недели, дата, месяц и год. Воскресенье – это «1», а суббота – это «7». И не забудьте убрать знаки комментария (т.е. 2 слеша) у этой строчки.

Настроив текущее время, вы можете загрузить на Arduino код ниже. Он написан Джоном Боксэллом (John Boxall) с сайта tronixstuff.com. Соответствующее руководство можно почитать тут.

// Автор – Джон Боксэлл (John Boxall), from http://tronixstuff.com

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68
// конвертируем обычные десятичные значения в двоично-десятичный код:
byte decToBcd(byte val){
  return( (val/10*16) + (val%10) );
}
// конвертируем двоично-десятичный код в обычные десятичные значения: 
byte bcdToDec(byte val){
  return( (val/16*10) + (val%16) );
}
void setup(){
  Wire.begin();
  Serial.begin(9600);
  // задаем текущее время;
  // секунды, минуты, часы, день недели, дата, месяц, год:
  // setDS3231time(30,42,16,5,13,10,16);
}
void setDS3231time(byte second, byte minute, byte hour, byte dayOfWeek, byte
dayOfMonth, byte month, byte year){
  // передаем данные о времени и дате на DS3231:
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  // выставляем регистр указателей DS3231 на регистр «00h»,
  // т.е. на регистр, в котором хранятся данные о секундах:
  Wire.write(0);
  Wire.write(decToBcd(second)); // задаем секунды
  Wire.write(decToBcd(minute)); // задаем минуты
  Wire.write(decToBcd(hour)); // задаем часы
  Wire.write(decToBcd(dayOfWeek));
  // задаем день недели (1 – это воскресенье, 7 – это суббота)
  Wire.write(decToBcd(dayOfMonth)); // задаем дату (от 1 до 31)
  Wire.write(decToBcd(month)); // задаем месяц
  Wire.write(decToBcd(year)); // задаем год (от 0 до 99)
  Wire.endTransmission();
}
void readDS3231time(byte *second,
byte *minute,
byte *hour,
byte *dayOfWeek,
byte *dayOfMonth,
byte *month,
byte *year){
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  // выставляем регистр указателей DS3231 на регистр «00h»:
  Wire.write(0);
  Wire.endTransmission();
  Wire.requestFrom(DS3231_I2C_ADDRESS, 7);
  // запрашиваем у DS3231 семь байтов начиная с регистра «00h»:
  *second = bcdToDec(Wire.read() & 0x7f);
  *minute = bcdToDec(Wire.read());
  *hour = bcdToDec(Wire.read() & 0x3f);
  *dayOfWeek = bcdToDec(Wire.read());
  *dayOfMonth = bcdToDec(Wire.read());
  *month = bcdToDec(Wire.read());
  *year = bcdToDec(Wire.read());
}
void displayTime(){
  byte second, minute, hour, dayOfWeek, dayOfMonth, month, year;
  // извлекаем данные из DS3231:
  readDS3231time(&second, &minute, &hour, &dayOfWeek, &dayOfMonth, &month,
  &year);
  // отправляем их на монитор порта:
  Serial.print(hour, DEC);
  // при показе конвертируем байтовую переменную в десятичное число:
  Serial.print(":");
  if (minute<10){
    Serial.print("0");
  }
  Serial.print(minute, DEC);
  Serial.print(":");
  if (second<10){
    Serial.print("0");
  }
  Serial.print(second, DEC);
  Serial.print(" ");
  Serial.print(dayOfMonth, DEC);
  Serial.print("/");
  Serial.print(month, DEC);
  Serial.print("/");
  Serial.print(year, DEC);
  Serial.print(" Day of week: ");  //  " День недели: "
  switch(dayOfWeek){
  case 1:
    Serial.println("Sunday");  //  "Воскресенье"
    break;
  case 2:
    Serial.println("Monday");  //  "Понедельник"
    break;
  case 3:
    Serial.println("Tuesday");  //  "Вторник"
    break;
  case 4:
    Serial.println("Wednesday");  //  "Среда"
    break;
  case 5:
    Serial.println("Thursday");  //  "Четверг"
    break;
  case 6:
    Serial.println("Friday");  //  "Пятница"
    break;
  case 7:
    Serial.println("Saturday");  //  "Суббота"
    break;
  }
}
void loop(){
  displayTime();
 // показываем на мониторе порта текущие данные RTC-модуля  
  delay(1000); // секундная задержка
}

Делаем так, чтобы время не сбивалось

Если вы не хотите, чтобы время сбрасывалось при каждом выключении RTC-модуля, вам нужно закомментировать функцию, которая задает текущее время, а потом загрузить скетч снова.

Это очень важный момент. Если этого не сделать, то при каждом сбросе RTC-модуля время тоже будет сбрасываться на то, чтобы было указано при первой настройке. То есть текущее время показано не будет.

Демонстрация

Откройте монитор порта на скорости 9600 бод, чтобы посмотреть результат. Ниже – монитор порта, показывающий текущую дату и время.

См.также

Внешние ссылки