Arduino:Примеры/Запись данных с датчиков в текстовый файл на ПК

Содержание

Знакомство с Arduino

Продукты

Основы

Справочник языка Arduino

Примеры

Библиотеки

Хакинг

Изменения

Сравнение языков Arduino и Processing

Проверка/Оформление/Редактирование: Мякишев Е.А.

Запись данных с датчиков в текстовый файл на ПК

Данный пример демонстрирует логирование считанных с датчиков данных в текстовый файл на вашем компьютере с использованием Arduino Leonardo. Arduino Leonardo обладает возможностью эмулировать работу USB-устройств(например, клавиатуры или мыши), в результате мы можем отправлять комбинации клавиш в виде команд или записывать данные в открытый текстовый файл.

В этом примере при нажатии кнопки, включится светодиод и запустится логирование данных, данные будут записываться в любой открытый в текущий момент текстовый файл. При повторном нажатии кнопки логирование выключается. Опрос данных и их запись происходит раз в секунду. В данном случае мы используем функцию millis()(возвращает количество миллисекунд с последнего сброса платы Arduino), а не delay(). Мы будем считывать и записывать данные каждый раз, когда функция millis() возвращает значение кратное 1000, тем самым создадим задержку в 1 секунду. В этом нам поможет % (оператор деления по модулю), который возвращает остаток от деления двух чисел. Например: при 1000%1000 мы получим 0, т.к. 1000/1000 = 1 и остаток 0; при 2000%1000 мы получим 0, т.к. 2000/1000 = 2 и остаток 0; при 1500%1000 мы получим 500, т.к. 1500/1000 = 1 и остаток 500 и т.д.

Необходимые компоненты

• Arduino Leonardo;
• Резистор 150 Ом, 1 шт.;
• Резистор 10 кОм, 2 шт.;
• Светодиод, 1 шт.;
• Фоторезистор, 1 шт.;
• Датчик температуры TMP36, 1 шт.;
• Кнопка, , 1 шт.;
• Макетная плата;
• Провода перемычки;

Монтажная схема

Соберите схему согласно монтажной схеме.

Код

Внимание! При использовании команды Keyboard.print() Arduino перехватит роль клавиатуры на себя. Поэтому, перед тем как вызывать эту команду, убедитесь, что вы все настроили правильно, чтобы внезапно не потерять контроль над компьютером при использовании этого скетча. Он специально устроен таким образом, что работает только при нажатии кнопки.

#include <Keyboard.h>  

#define TEMP   0                                       // датчик температуры подключаем к 0-му аналоговому выводу
#define LIGHT  1                                       // фоторезистор подключаем к 1-му аналоговому выводу
#define LED    3                                       // светодиод подключаем к 3-му выводу
#define BUTTON 2                                       // кнопку подключаем к 2-му выводу

boolean lastButton = LOW;                              // последнее состояние кнопки
boolean currentButton = LOW;                           // текущее состояние кнопки
boolean running = false;                               // по умолчанию логирование данных выключено
int counter = 1;                                       // индекс записываемых данных

void setup()
{
  pinMode (LED, OUTPUT);                               // устанавливаем вывод LED(т.е. 3-ий) как выход
  Keyboard.begin();                                    // запускаем эмуляцию клавиатуры
}

void loop()
{
  currentButton = debounce(lastButton);                // считываем состояние кнопки с использованием функции "антидребезга"
 
  if (lastButton == LOW && currentButton == HIGH)      // если кнопку нажали, то
    running = !running;                                // инвертируем переменную running для включения/выключения логирования данных
  
  lastButton = currentButton;                          // сохраняем текущее состояние кнопки как последнее состояние
 
  if (running)                                         // если логирование включено
  {
    digitalWrite(LED, HIGH);                           // включаем светодиод
    if (millis() % 1000 == 0)                          // если время кратно 1000
    {
      int temperature = analogRead(TEMP);              // считываем значение температуры
      int brightness = analogRead(LIGHT);              // считываем значение с фоторезистора
      Keyboard.print(counter);                         // печатаем индекс
      Keyboard.print(",");                             // печатаем запятую
      Keyboard.print(temperature);                     // печатаем температуру
      Keyboard.print(",");                             // печатаем запятую
      Keyboard.print(brightness);                      // печатаем значение освещенности
      Keyboard.print("\n");                            // переходим на новую строку
      counter++;                                       // увеличиваем значение индекса записываемых значений на 1
    }
  }
  else                                                 // иначе, логирование выключено
  {
    digitalWrite(LED, LOW);                            // отключаем светодиод
  }
}

/*
* Функция для предотвращения дребезга контакта
* last    - последнее состояние кнопки
* current - текущее состояние кнопки
*/
boolean debounce(boolean last)
{
  boolean current = digitalRead(BUTTON);              // считываем состояние кнопки
  if (last != current)                                // если предыдущее и текущее состояние кнопки отлючаются
  {
    delay(5);                                         // ждем 5мс
    current = digitalRead(BUTTON);                    // считываем заново
  }
  return current;                                     // возвращаем текущее состояние кнопки
}