Arduino:Примеры/Управление курсором мыши

Содержание

Знакомство с Arduino

Продукты

Основы

Справочник языка Arduino

Примеры

Библиотеки

Хакинг

Изменения

Сравнение языков Arduino и Processing

Проверка/Оформление/Редактирование: Мякишев Е.А.

Управление курсором мыши

Данный пример демонстрирует управление курсором мыши с использованием Arduino Leonardo. Arduino Leonardo обладает возможностью эмулировать работу USB-устройств(например, клавиатуры или мыши), в результате с помощью джойстика и нескольких кнопок мы сможем превратить Arduino Leonardo в мышку.

В этом примере джойстик будет перемещать курсор мыши, а 3 кнопки выполнять функции левой, правой и средней кнопки. К рукоятке джойстика подсоединены два потенциометра. При перемещении рукоятки, значения сопротивлений потенциометров меняется.

Необходимые компоненты

• Arduino Leonardo;
• Резистор 150 Ом, 1 шт.;
• Резистор 10 кОм, 3 шт.;
• Кнопка, , 3 шт.;
• Джойстик, 1 шт.;
• Макетная плата;
• Провода перемычки;

Монтажная схема

Соберите схему согласно монтажной схеме.

Код

Внимание! При использовании команды Keyboard.print() Arduino перехватит роль клавиатуры на себя. Поэтому, перед тем как вызывать эту команду, убедитесь, что вы все настроили правильно, чтобы внезапно не потерять контроль над компьютером при использовании этого скетча. Он специально устроен таким образом, что работает только при нажатии кнопки.

#include <Mouse.h>                             // подключаем библиотеку для эмуляции мыши

#define LEFT_BUTTON   4                        // левую кнопку подключаем к 4-му выводу
#define MIDDLE_BUTTON 3                        // среднюю кнопку подключаем к 3-му выводу
#define RIGHT_BUTTON  2                        // правую кнопку подключаем к 2-му выводу
#define X_AXIS        0                        // пин оси X джойстика подключаем к 0-му аналоговому входу
#define Y_AXIS        1                        // пин оси Y джойстика подключаем к 1-му аналоговому входу

void setup()
{
  Mouse.begin();
}

void loop()
{
  int xVal = readJoystick(X_AXIS);            // считываем отклонение джойстика по оси X
  int yVal = readJoystick(Y_AXIS);            // считываем отклонение джойстика по оси Y

  Mouse.move(xVal, yVal, 0);                  // перемещаем курсор
                                              // при отрицательном значении по оси X (xVal) курсор будет перемещаться влево
                                              // при положительном значении по оси X (xVal) курсор будет перемещаться вправо
                                              // при отрицательном значении по оси Y (yVal) курсор будет перемещаться вниз
                                              // при положительном значении по оси Y (yVal) курсор будет перемещаться вверх
                                              // при нулевом значении по оси X (xVal) или по оси Y (yVal) курсор будет неподвижен 
                                              // третий параметр данной функции отвечает за управление колесом прокрутки 

  readButton(LEFT_BUTTON, MOUSE_LEFT);        // считываем состояние левой кнопки мыши и при нажатии выполняем левый клик 
  readButton(MIDDLE_BUTTON, MOUSE_MIDDLE);    // считываем состояние средней кнопки мыши и при нажатии выполняем клик средней кнопки 
  readButton(RIGHT_BUTTON, MOUSE_RIGHT);      // считываем состояние правой кнопки мыши и при нажатии выполняем правый клик 
 
  delay(5);                                   // задержка отклика
}

// Считываем значение джойстика, масштабируем его и добавляем "мертвый диапазон" в середине
int readJoystick(int axis)
{ 
  int val = analogRead(axis);                 // считываем значение отклонения
  val = map(val, 0, 1023, -10, 10);           // масштабируем считанное значение
                                             
  if (val <= 2 && val >= -2)                  // создаём мертвую зону, чтобы предотвратить дрейф курсора
    return 0; 
 
  else                                        // возвращаем масштабированное значение
    return val;
}

// Чтение состояния кнопки и выдача команды мыши
void readButton(int pin, char mouseCommand)
{
  // если нажали кнопку
  if (digitalRead(pin) == HIGH)
  {
    if (!Mouse.isPressed(mouseCommand))     // если еще не была нажата
    {
      Mouse.press(mouseCommand);            // нажимаем и удерживаем кнопку мыши
    }
  }
  // иначе 
  else
  {
    if (Mouse.isPressed(mouseCommand))      // если кнопка мыши была нажата
    {
      Mouse.release(mouseCommand);          // отпускаем кнопку мыши
    }
  }
}