Processing:Примеры/Дым при помощи системы частиц (Дэниэл Шиффман)

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску


Перевод: Максим Кузьмин (Cubewriter) Контакты:</br>* Skype: cubewriter</br>* E-mail: cubewriter@gmail.com</br>* Максим Кузьмин на freelance.ru
Проверка/Оформление/Редактирование: Мякишев Е.А.


Cat poo.png Черновик


Описание[1]

Простой эффект дыма при помощи системы частиц. Каждая частица рендерится как изображение с наложенной на нее альфа-маской.

Пример

ParticleSystem ps;

void setup() {
  size(640, 360);
  PImage img = loadImage("texture.png");
  ps = new ParticleSystem(0, new PVector(width/2, height-60), img);
}

void draw() {
  background(0);

  // рассчитываем силу «ветра» на основе
  // движения курсора мыши по оси X:
  float dx = map(mouseX, 0, width, -0.2, 0.2);
  PVector wind = new PVector(dx, 0);
  ps.applyForce(wind);
  ps.run();
  for (int i = 0; i < 2; i++) {
    ps.addParticle();
  }

  // рисуем стрелку, демонстрирующую силу «ветра»:
  drawVector(wind, new PVector(width/2, 50, 0), 500);
}

// рисуем векторный объект «v» как стрелку на позиции «loc»:
void drawVector(PVector v, PVector loc, float scayl) {
  pushMatrix();
  float arrowsize = 4;
  // перемещаем стрелку на позицию, где ее нужно отрисовать: 
  translate(loc.x, loc.y);
  stroke(255);
  // вызываем метод heading(), 
  // чтобы извлечь угол вращения вектора («0» - это верх):
  rotate(v.heading());
  // считываем длину вектора и, если необходимо,
  // масштабируем его к какому-либо диапазону (scayl):
  float len = v.mag()*scayl;
  // рисуем три линии, чтобы создать стрелку
  // (она будет смотреть вверх, 
  // но мы повернем ее в нужном направлении):
  line(0, 0, len, 0);
  line(len, 0, len-arrowsize, +arrowsize/2);
  line(len, 0, len-arrowsize, -arrowsize/2);
  popMatrix();
}


// класс для управления группой объектов Particle;
// для хранения объектов Particle будет использован ArrayList 

class ParticleSystem {

  ArrayList<Particle> particles;    // объект ArrayList
                                    // для хранения всех частиц
  PVector origin;                   // точка, из которой
                                    // будут извергаться частицы
  PImage img;

  ParticleSystem(int num, PVector v, PImage img_) {
    particles = new ArrayList<Particle>();           // инициализируем
                                                     // ArrayList  
    origin = v.copy();                          // сохраняем точку, 
                                                // из которой будут
                                                // извергаться частицы 
    img = img_;
    for (int i = 0; i < num; i++) {
      particles.add(new Particle(origin, img));  // добавляем в 
                                                 // ArrayList 
                                                 // количество частиц,
                                                 // заданное в «num»
    }
  }

  void run() {
    for (int i = particles.size()-1; i >= 0; i--) {
      Particle p = particles.get(i);
      p.run();
      if (p.isDead()) {
        particles.remove(i);
      }
    }
  }

  // метод для применения вектора силы
  // на все частицы, в данный момент находящиеся в системе:
  void applyForce(PVector dir) {
    // продвинутая версия цикла for() !!!
    for (Particle p : particles) {
      p.applyForce(dir);
    }
  }  

  void addParticle() {
    particles.add(new Particle(origin, img));
  }
}



// простой класс Particle, рендерит частицу в виде изображения

class Particle {
  PVector loc;
  PVector vel;
  PVector acc;
  float lifespan;
  PImage img;

  Particle(PVector l, PImage img_) {
    acc = new PVector(0, 0);
    float vx = randomGaussian()*0.3;
    float vy = randomGaussian()*0.3 - 1.0;
    vel = new PVector(vx, vy);
    loc = l.copy();
    lifespan = 100.0;
    img = img_;
  }

  void run() {
    update();
    render();
  }

  // метод для применения вектора силы к объекту Particle;
  // обратите внимание, что мы здесь игнорируем «массу»:
  void applyForce(PVector f) {
    acc.add(f);
  }  

  // метод для обновления позиции:
  void update() {
    vel.add(acc);
    loc.add(vel);
    lifespan -= 2.5;
    acc.mult(0); // стираем данные об ускорении
  }

  // метод для отрисовки:
  void render() {
    imageMode(CENTER);
    tint(255, lifespan);
    image(img, loc.x, loc.y);
    // вместо изображения можно воспользоваться эллипсом:
    // fill(255,lifespan);
    // noStroke();
    // ellipse(loc.x,loc.y,img.width,img.height);
  }

  // частица еще видна?
  boolean isDead() {
    if (lifespan <= 0.0) {
      return true;
    } else {
      return false;
    }
  }
}

См.также

Внешние ссылки