Processing:Примеры/Несколько систем частиц

Материал из Онлайн справочника
Перейти к навигацииПерейти к поиску

Перевод: Максим Кузьмин
Проверка/Оформление/Редактирование: Мякишев Е.А.


Описание[1]

Кликните мышкой по экрану, чтобы создать в месте клика «фонтан» частиц.

Каждый «фонтан» – это один экземпляр системы частиц, извергающей объекты Particle и CrazyParticle (это подкласс Particle). Обратите внимание на то, что в этом скетче используются полиморфизм и наследование.

Пример

ArrayList<ParticleSystem> systems;

void setup() {
  size(640, 360);
  systems = new ArrayList<ParticleSystem>();
}

void draw() {
  background(0);
  for (ParticleSystem ps : systems) {
    ps.run();
    ps.addParticle();
  }
  if (systems.isEmpty()) {
    fill(255);
    textAlign(CENTER);
    text("click mouse to add particle systems", width/2, height/2);
     //  "Кликните, чтобы создать систему частиц"
  }
}

void mousePressed() {
  systems.add(new ParticleSystem(1, new PVector(mouseX, mouseY)));
}


// для управления частицами Particle
// будет использован объект ArrayList

class ParticleSystem {

  ArrayList<Particle> particles;    // объект ArrayList
                                    // для хранения всех частиц
  PVector origin;                   // точка, из которой
                                    // будут извергаться частицы

  ParticleSystem(int num, PVector v) {
    particles = new ArrayList<Particle>();  // инициализируем
                                            // список ArrayList
    origin = v.copy();                      // сохраняем точку
                                            // извержения частиц 
    for (int i = 0; i < num; i++) {
      particles.add(new Particle(origin));  // добавляем в ArrayList 
                                            // количество частиц,
                                            // равное значению в «num»
    }
  }


  void run() {
    // при помощи цикла for() проходим через ArrayList задом наперед,
    // т.к. во время итерации также происходит удаление элементов: 
    for (int i = particles.size()-1; i >= 0; i--) {
      Particle p = particles.get(i);
      p.run();
      if (p.isDead()) {
        particles.remove(i);
      }
    }
  }

  void addParticle() {
    Particle p;
    // добавляем в систему либо Particle, либо CrazyParticle:
    if (int(random(0, 2)) == 0) {
      p = new Particle(origin);
    } 
    else {
      p = new CrazyParticle(origin);
    }
    particles.add(p);
  }

  void addParticle(Particle p) {
    particles.add(p);
  }

  // метод для проверки того, есть ли еще частицы в системе частиц: 
  boolean dead() {
    return particles.isEmpty();
  }
}



// CrazyParticle – это подкласс класса Particle

class CrazyParticle extends Particle {

  // просто добавляем в CrazyParticle одну новую переменную;
  // все остальные поля этот подкласс наследует у Particle,
  // поэтому нам не придется их переписывать оттуда!
  float theta;

  // конструктор CrazyParticle может вызвать
  // конструктор родительского класса (суперкласса):
  CrazyParticle(PVector l) {
    // метод super() должен быть первым методом,
    // вызываемым внутри конструктора подкласса;
    // он сделает все, что делает конструктор суперкласса Particle:
    super(l);
    // еще одна строчка кода, добавляющая новую переменную «theta»:
    theta = 0.0;
  }

  // обратите внимание, что у нас здесь нет метода run(),
  // т.к. он наследуется от суперкласса Particle

  // этот метод update() заменяет собой
  // метод update() родительского класса:
  void update() {
    super.update();
    // увеличиваем значение вращения,
    // используя значение горизонтальной скорости:
    float theta_vel = (velocity.x * velocity.mag()) / 10.0f;
    theta += theta_vel;
  }

  // этот метод display() заменяет собой
  // метод display() родительского класса:
  void display() {
    // рендерим эллипс как обычную частицу:
    super.display();
    // добавляем вращающуюся линию:
    pushMatrix();
    translate(position.x, position.y);
    rotate(theta);
    stroke(255, lifespan);
    line(0, 0, 25, 0);
    popMatrix();
  }
}


// простой класс Particle

class Particle {
  PVector position;
  PVector velocity;
  PVector acceleration;
  float lifespan;

  Particle(PVector l) {
    acceleration = new PVector(0, 0.05);
    velocity = new PVector(random(-1, 1), random(-2, 0));
    position = l.copy();
    lifespan = 255.0;
  }

  void run() {
    update();
    display();
  }

  // метод для обновления позиции:
  void update() {
    velocity.add(acceleration);
    position.add(velocity);
    lifespan -= 2.0;
  }

  // метод для отрисовки:
  void display() {
    stroke(255, lifespan);
    fill(255, lifespan);
    ellipse(position.x, position.y, 8, 8);
  }

  // частица еще видна?
  boolean isDead() {
    return (lifespan < 0.0);
  }
}

См.также

Внешние ссылки