Processing:Примеры/Создание многогранника

Содержание

Среда разработки Processing

Справочник языка Processing

Библиотеки

Примеры

Режимы программирования

Перевод: Максим Кузьмин

Проверка/Оформление/Редактирование: Мякишев Е.А.

Описание

Какой ваш любимый многоугольник? Пятиугольник? Шестиугольник? Семиугольник? Нет? Как насчет двадцатиугольника? Функция polygon(), созданная для этого примера, может нарисовать любой стандартный прямоугольник. Попробуйте поместить разные значения в вызовы функции polygon() внутри блока draw(), чтобы понять, как она работает. Например, изменение значения в 4-ом параметре задает количество углов рисуемого многоугольника.

Пример

void setup() {
  size(640, 360);
}

void draw() {
  background(102);
  
  pushMatrix();
  translate(width*0.2, height*0.5);
  rotate(frameCount / 200.0);
  polygon(0, 0, 82, 3);  // треугольник
  popMatrix();
  
  pushMatrix();
  translate(width*0.5, height*0.5);
  rotate(frameCount / 50.0);
  polygon(0, 0, 80, 20);  // двадцатигранник
  popMatrix();
  
  pushMatrix();
  translate(width*0.8, height*0.5);
  rotate(frameCount / -100.0);
  polygon(0, 0, 70, 7);  // шестиугольник
  popMatrix();
}

void polygon(float x, float y, float radius, int npoints) {
  float angle = TWO_PI / npoints;
  beginShape();
  for (float a = 0; a < TWO_PI; a += angle) {
    float sx = x + cos(a) * radius;
    float sy = y + sin(a) * radius;
    vertex(sx, sy);
  }
  endShape(CLOSE);
}