Processing:Справочник языка Processing/modelZ()

Содержание

Среда разработки Processing

Справочник языка Processing

Библиотеки

Примеры

Режимы программирования

Перевод: Максим Кузьмин

Проверка/Оформление/Редактирование: Мякишев Е.А.

modelZ()

Обозначение

modelZ()

Описание

Возвращает значение Z на основе заданных XYZ-координат, учитывая все примененные трансформации (масштабирование, вращение, перемещение и т.д.). Это значение Z в дальнейшем можно использовать, чтобы поместить другой объект на исходную позицию предыдущего – то есть, когда на него еще не было наложено никаких трансформаций.

К примеру, методы modelX(), modelY() и modelZ() сохраняют данные о месторасположении куба в пространстве после того, как к нему были применены несколько команд перемещения и вращения. После вызова popMatrix() эти трансформации работать уже не будут, однако координаты XYZ для значения Z, возвращенные методом modelZ(), можно будет использовать, чтобы поместить в то же место новый куб.

Синтаксис

modelZ(x, y, z)

Параметры

x – координата X для отслеживания значения Z. Тип данных – float
y – координата Y для отслеживания значения Z. Тип данных – float
z – координата Z для отслеживания значения Z. Тип данных – float

Возвращаемое значение

Тип данных – float

Пример

void setup() {
  size(500, 500, P3D);
  noFill();
}

void draw() {
  background(0);
 
  pushMatrix();
  // начинаем в середине экрана:
  translate(width/2, height/2, -200);     
  // несколько случайных вращений – чтобы было поинтересней:
  rotateY(1.0); //yrot);
  rotateZ(2.0); //zrot);
  // немного вращаем по оси X с каждым кадром:
  rotateX(frameCount / 100.0);
  // смещаем от центра:
  translate(0, 150, 0);
 
  // рисуем куб с белым контуром на (0, 0, 0):
  stroke(255);
  box(50);
 
  // куб был нарисован на (0, 0, 0), сохраняем данные этого места:
  float x = modelX(0, 0, 0);
  float y = modelY(0, 0, 0);
  float z = modelZ(0, 0, 0);
  // стираем все трансформации:
  popMatrix();

  // рисуем еще один куб на тех же координатах (x, y, z),
  // что и предыдущий:
  pushMatrix();
  translate(x, y, z);
  stroke(255, 0, 0);
  box(50);
  popMatrix();
}